{
	gsub("-"," ")
	for(i=2;i<=NF;i++)	_data[++_N]=$i
}
END{
	_N=1
	if(_str(2)!="BM")	exit
	fsize =_num(4);	# ファイルサイズ=0x3fe(1022バイト)
	       _num(4);
	offset=_num(4);	# オフセット=0x3e
	hsize =_num(4);	# ヘッダサイズ=0x28
	W     =_num(4);	# W=96(SCREEN_W)
	H     =_num(4);	# H=80(SCREEN_H)
	nplane=_num(2);	# プレーン数=1
	bpp   =_num(2);	# ピクセルのビット数=1
	       _num(4);	# 圧縮なし
	dsize =_num(4);	# データサイズ=0x3c0(960バイト)
	xppm  =_num(4);
	yppm  =_num(4);
	ncolor=_num(4);
	ncolorx=_num(4);
	_num(4);_num(4);	#パレットデータ空読み
	for(y=0;y<H;y++)	for(x=0;x<W/8;x++)	data[x,y]=_num(1)

	print "uint8_t vram[]={";
	for(y=H-1;y>=0;y--){
		printf "\t";
		for(x=0;x<W/8;x++)	printf data[x,y] ",";
		print "";
	}
	print "};";
}
function _num(n,	m){
	if(n==0)	return 0
	m=d(_data[_N++])
	if(n==1)	return m
	else		return _num(n-1)*256+m
}
function _str(n){
	if(n==1)	return sprintf("%c",d(_data[_N++]))
	else		return sprintf("%c",d(_data[_N++])) _str(n-1)
}
function d(x,	c){
	if(x=="")	return 0
	else if(length(x)==1){
		c=tolower(x)
		if(c=="a")		x=10
		else if(c=="b")	x=11
		else if(c=="c")	x=12
		else if(c=="d")	x=13
		else if(c=="e")	x=14
		else if(c=="f")	x=15
		return x
	}else	return d(substr(x,1,length(x)-1))*16+d(substr(x,length(x)))
}